GUI用のボタンコントロールを作成します。
GUICtrlCreateButton ( "text", left, top [, width [, height [, style [, exStyle]]]] )
パラメータ
| text | ボタンコントロールのテキスト。 |
| left | コントロールの左端。-1を使用するとGUICoordModeに基づいて左端位置が計算されます。 |
| top | コントロールの上端。-1を使用するとGUICoordModeに基づいて上端位置が計算されます。 |
| width | [オプション] コントロールの幅(デフォルトではテキストの幅に合わせて自動調整されます)。 |
| height | [オプション] コントロールの高さ(デフォルトではテキストの高さに合わせて自動調整されます)。 |
| style | [オプション]
コントロールのスタイルを定義。GUIコントロールスタイル付録を参照。 デフォルト ( -1) ： なし。 強制適用されるスタイル ： $WS_TABSTOP、$BS_NOTIFY |
| exStyle | [オプション] コントロールの拡張スタイルを定義。拡張スタイル表を参照。 |
返し値
| 成功 | 新しく作成したコントロールの識別子(コントロールID)を返します。 |
| 失敗 | 0を返します。 |
注意
コントロールの情報を設定/変更する方法についてはGUICtrlUpdate...を参照。
関連
GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg
例
#include <GUIConstantsEx.au3>
Opt('MustDeclareVars', 1)
Example()
Func Example()
Local $Button_1, $Button_2, $msg
GUICreate("My GUI Button") ; 表示時に中央に表示されるダイアログボックスを作成
Opt("GUICoordMode", 2)
$Button_1 = GUICtrlCreateButton("Run Notepad", 10, 30, 100)
$Button_2 = GUICtrlCreateButton("Button Test", 0, -1)
GUISetState() ; ボタンを2つ持つダイアログボックスを表示
; ダイアログが閉じられるまでGUIを実行
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
Case $msg = $Button_1
Run('Notepad.exe') ; メモ帳を実行/開く
Case $msg = $Button_2
MsgBox(0, 'Testing', 'Button 2 was pressed') ; ボタン2が押された場合のデモ
EndSelect
WEnd
EndFunc ;==>Example