Function Reference

GUICtrlCreateTabItem

GUI用のタブアイテムコントロールを作成します。

GUICtrlCreateTabItem ( "text" )

 

パラメータ

text コントロールのテキスト。

 

返し値

成功 新しく作成したコントロールの識別子(コントロールID)を返します。
失敗 0を返します。

 

注意

さらに情報を設定するにはGUICtrlUpdate...を参照してください。

ダイアログボックスが開いた際に指定したタブアイテムが表示されるように選択するにはGUICtrlSetState(-1,$GUI_SHOW)を設定します。例を参照してください。

タブコントロールを終了するにはヌルテキスト""を使って最後の"タブアイテム"コントロールを作成してください。(以降の)"タブアイテム"コントロールは描画されません。

アドバンスドモードを使用すると、GUICtrlRead($tab,1)はクリックされたタブアイテムのインデックスの代わりにコントロールIDを返すようになります。

既存のタブアイテムの上に新しいコントロールを作成するにはまずGUISwitch($hWin,$tabitem)でタブアイテムを選択し、その後新しいコントロールを作成します。GUICtrlCreateTabItem("")でタブアイテム作成を終了するのを忘れないでください。

 

関連

GUICtrlSetState, GUISwitch, GUIGetMsg, GUICtrlRead, GUIEventOptions (Option), GUICtrlCreateTab

 


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $tab, $tab0, $tab0OK, $tab0input
    Local $tab1, $tab1combo, $tab1OK
    Local $tab2, $tab2OK, $msg
   
    GUICreate("My GUI Tab", 250, 150); 表示時に中央に表示されるダイアログボックスを作成

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    $tab = GUICtrlCreateTab(10, 10, 200, 100)

    $tab0 = GUICtrlCreateTabItem("tab0")
    GUICtrlCreateLabel("label0", 30, 80, 50, 20)
    $tab0OK = GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    $tab0input = GUICtrlCreateInput("default", 80, 50, 70, 20)

    $tab1 = GUICtrlCreateTabItem("tab----1")
    GUICtrlCreateLabel("label1", 30, 80, 50, 20)
    $tab1combo = GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo", "Jon"); デフォルトはJon
    $tab1OK = GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    $tab2 = GUICtrlCreateTabItem("tab2")
    GUICtrlSetState(-1, $GUI_SHOW); 最初に表示される
    GUICtrlCreateLabel("label2", 30, 80, 50, 20)
    $tab2OK = GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem(""); タブアイテム定義終了

    GUICtrlCreateLabel("Click on tab and see the title", 20, 130, 250, 20)

    GUISetState()

    ; ダイアログが閉じられるまでGUIを実行
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        If $msg = $tab Then
            ; クリックされたタブを表示
            WinSetTitle("My GUI Tab", "", "My GUI Tab" & GUICtrlRead($tab))
        EndIf
    WEnd
EndFunc   ;==>Example