Function Reference

GUICtrlSetFont

コントロールのフォントを設定します。

GUICtrlSetFont (controlID, size [, weight [, attribute [, fontname[, quality]]]] )

 

パラメータ

controlID GUICtrlCreate...関数によって返されるコントロール識別子(コントロールID)。
size フォントサイズ (デフォルトは8.5)。
weight [オプション] フォントの太さ (デフォルトは400 = ノーマル)。
attribute [オプション] 文字形式を定義。イタリック:2 下線:4 取り消し線:8 (設定したいスタイルの値を足し合わせる。2+4 = イタリックで下線付き)。
fontname [オプション] 使用するフォント名。
quality [オプション] 選択するフォントの品質 (デフォルトはPROOF_QUALITY=2)

 

返し値

成功 1を返します。
失敗 0を返します。

 

注意

デフォルトではコントロールはGUISetFontで設定されたフォントを使用します。

sizeには8.5といったように小数点を使うことができます。

ラベルなど一部のコントロールではデフォルトのサイズをWindowsのテーマの値に従う9ではなく8.5にできます。

WindowsのフォントのリストとそれらがどのバージョンのWindowsでサポートされているかについては付録を参照してください。

qualityパラメータについてはMSDNを調べてください。WindowsXPのインストールバージョンによってはCLEARTYPE_QUALITY=5であることが必要になります。

 

関連

GUICtrlCreate..., GUISetFont

 


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $font, $msg
   
    GUICreate("My GUI")  ; 表示時に中央に表示されるダイアログボックスを作成

    $font = "Comic Sans MS"
    GUICtrlCreateLabel("underlined label", 10, 20)
    GUICtrlSetFont(-1, 9, 400, 4, $font)    ; 下線付きの文字を表示

    GUICtrlCreateLabel("italic label", 10, 40)
    GUICtrlSetFont(-1, 9, 400, 2, $font)    ; イタリック体の文字を表示

    GUISetFont(9, 400, 8, $font)    ; 取り消し線付きの文字を表示
    GUICtrlCreateLabel("strike label", 10, 60)

    GUISetState()       ; 空のダイアログボックスを表示

    ; ダイアログが閉じられるまでGUIを実行
    While 1
        $msg = GUIGetMsg()
       
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example