コントロールによって使用されるサイズ変更方法を定義します。
GUICtrlSetResizing ( controlID, resizing )
パラメータ
| controlID | GUICtrlCreate...関数によって返されるコントロール識別子(コントロールID)。 |
| resizing | 使用する値については下記のドッキング値表を参照してください(必要な場合は複数の値を足し合わせてください)。 |
返し値
| 成功 | 1を返します。 |
| 失敗 | 0を返します。 |
注意
GUIウィンドウがサイズ変更された場合、コントロールにもそれが反映されます。この関数でどのように反映されるかを決定します。GUIウィンドウをサイズ変更できるようにするには作成時に$WS_SIZEBOX スタイルと$WS_SYSMENUスタイルを設定する必要があります。GUICreateを参照してください。| サイズ変更 | 値 | サイズ変更基準 |
| $GUI_DOCKAUTO | 1 | サイズ変更し、新しいウィンドウサイズに基づいて位置変更をする。 |
| $GUI_DOCKLEFT | 2 | 左端 |
| $GUI_DOCKRIGHT | 4 | 右端 |
| $GUI_DOCKHCENTER | 8 | 水平方向中央を基準に相対位置を保ちます。 |
| $GUI_DOCKTOP | 32 | 上端 |
| $GUI_DOCKBOTTOM | 64 | 下端 |
| $GUI_DOCKVCENTER | 128 | 垂直方向中央を基準に相対位置を保ちます。 |
| $GUI_DOCKWIDTH | 256 | 幅を変更しません。 |
| $GUI_DOCKHEIGHT | 512 | 高さを変更しません。 |
| サイズ変更の組み合わせ | ||
| $GUI_DOCKSIZE | 768 | (256+512) サイズを変更しません。 |
| $GUI_DOCKMENUBAR | 544 | (512+32) コントロールはウィンドウの上端に高さを変えずにとどまります。 |
| $GUI_DOCKSTATEBAR | 576 | (512+64) コントロールはウィンドウの下端に高さを変えずにとどまります。 |
| $GUI_DOCKALL | 802 | (2+32+256+512) コントロールはサイズ変更で位置移動しません。 |
| $GUI_DOCKBORDERS | 102 | (2+4+32+64) コントロールがウィンドウと同様にサイズ変更されます。 |
関連
GUIResizeMode (Option), GUIEventOptions (Option), GUICtrlCreate...
例
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
Opt('MustDeclareVars', 1)
Example()
Func Example()
Local $nEdit, $nOk, $nCancel, $msg
Opt("GUICoordMode", 2)
GUICreate("My InputBox", 190, 114, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; 定義開始
GUISetIcon("Eiffel Tower.ico")
GUISetFont(8, -1, "Arial")
GUICtrlCreateLabel("Prompt", 8, 7) ; プロンプト情報を付加
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP)
$nEdit = GUICtrlCreateInput("Default", -1, 3, 175, 20, $ES_PASSWORD) ; 入力欄を付加
GUICtrlSetState($nEdit, $GUI_FOCUS)
GUICtrlSetResizing($nEdit, $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)
$nOk = GUICtrlCreateButton("OK", -1, 3, 75, 24) ; GUIを閉じるためのボタンを付加
GUICtrlSetResizing($nOk, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)
$nCancel = GUICtrlCreateButton("Annuler", 25, -1) ; GUIを閉じるためのボタンを付加
GUICtrlSetResizing($nCancel, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)
GUISetState() ; GUIを表示
; ダイアログが閉じられるまでGUIを実行
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
EndFunc ;==>Example