Function Reference

TrayItemSetState

トレイのメニュー/アイテムコントロールの状態を設定します。

TrayItemSetState ( controlID, state )

 

パラメータ

controlID TrayCreateItemTrayCreateMenuによって返されるコントロール識別子(コントロールID)
state 下記の状態表を参照。

 

返し値

成功 1を返します。
失敗 0を返します。

 

注意

    状態表
状態 コメント
変化なし 0
$TRAY_CHECKED 1 メニューアイテムがチェックされます。
$TRAY_UNCHECKED 4 メニューアイテムのチェックがはずされます。
$TRAY_ENABLE 64 メニューアイテムが有効になります。
$TRAY_DISABLE 128 メニューアイテムがグレイアウトします。
$TRAY_FOCUS 256 メニューアイテムが選択されます。
$TRAY_DEFAULT 512 メニューアイテムがデフォルトメニューアイテムに設定されます。

状態の値は足し合わせることができます。例えば$TRAY_CHECKED + $TRAY_DEFAULTを使用するとメニューアイテムはチェックされデフォルトに設定されます。

$TRAY_DEFAULT状態をリセット/解除したい場合はこの関数を使用して他の状態、例えば$TRAY_ENABLEを設定します。
上記の定数は#include <Constants.au3>で定義されています。

 

関連

TrayItemGetState, TrayCreateItem, TrayCreateMenu, TraySetState

 


#Include <Constants.au3>
#NoTrayIcon

Opt("TrayMenuMode",1)   ; デフォルトのトレイメニューアイテム(スクリプト 停止/終了)を非表示

$chkitem        = TrayCreateItem("Check it")
TrayCreateItem("")
$checkeditem    = TrayCreateItem("Checked")
TrayCreateItem("")
$exititem       = TrayCreateItem("Exit")

TraySetState()

While 1
    $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $chkitem
            TrayItemSetState($checkeditem,$TRAY_CHECKED)
        Case $msg = $exititem
            ExitLoop
    EndSelect
WEnd

Exit