特別なトレイアクションが起きた際に呼ばれるユーザー定義関数を定義します。
TraySetOnEvent ( specialID, "function" )
パラメータ
| specialID | 下記の特別ID表を参照。 |
| function | 呼ばれるユーザー関数の名前 |
返し値
| 成功 | 1を返します。 |
| 失敗 | 0を返します。 |
| @error: | "function"が定義されていない場合、1 |
注意
OnEvent関数はTrayOnEventModeオプションが1に設定されている場合のみ呼ばれます。このモードの際はTrayGetMsgは使用されません。| 特別ID | 値 | コメント |
| $TRAY_EVENT_SHOWICON | -3 | トレイアイコンが表示されます。 |
| $TRAY_EVENT_HIDEICON | -4 | トレイアイコンが非表示になります。 |
| $TRAY_EVENT_FLASHICON | -5 | ユーザーがトレイアイコン点滅をオンにした。 |
| $TRAY_EVENT_NOFLASHICON | -6 | ユーザーがトレイアイコン点滅をオフにした。 |
| $TRAY_EVENT_PRIMARYDOWN | -7 | マウス第1ボタンがトレイアイコン上でプッシュされた。 |
| $TRAY_EVENT_PRIMARYUP | -8 | マウス第1ボタンがトレイアイコン上でリリースされた。 |
| $TRAY_EVENT_SECONDARYDOWN | -9 | マウス第2ボタンがトレイアイコン上でプッシュされた。 |
| $TRAY_EVENT_SECONDARYUP | -10 | マウス第2ボタンがトレイアイコン上でリリースされた。 |
| $TRAY_EVENT_MOUSEOVER | -11 | マウスカーソルがトレイアイコン上を通過した。 |
| $TRAY_EVENT_PRIMARYDOUBLE | -13 | マウス第1ボタンがトレイアイコン上で２度プッシュされた。 |
| $TRAY_EVENT_SECONDARYDOUBLE | -14 | マウス第2ボタンがトレイアイコン上で２度プッシュされた。 |
関連
TrayOnEventMode (Option), TrayItemSetOnEvent, TraySetClick
例
#include <Constants.au3>
#NoTrayIcon
Opt("TrayOnEventMode",1)
Opt("TrayMenuMode",1) ; デフォルトのトレイメニューアイテム(スクリプト 停止/終了)を非表示
$exit = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1,"ExitEvent")
TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE,"SpecialEvent")
TraySetOnEvent($TRAY_EVENT_SECONDARYUP,"SpecialEvent")
TraySetState()
While 1
Sleep(10) ; アイドリングループ
WEnd
Exit
; 関数
Func SpecialEvent()
Select
Case @TRAY_ID = $TRAY_EVENT_PRIMARYDOUBLE
Msgbox(64,"SpecialEvent-Info","Primary mouse button double clicked.")
Case @TRAY_ID = $TRAY_EVENT_SECONDARYUP
Msgbox(64,"SpecialEvent-Info","Secondary mouse button clicked.")
EndSelect
EndFunc
Func ExitEvent()
Exit
EndFunc