Function Reference

_Date_Time_GetSystemTime

UTC表現の現在のシステム日時を取得します。

#Include <Date.au3>
_Date_Time_GetSystemTime()

 

パラメータ

なし。

 

 

返し値

現在のシステム日時の$tagSYSTEMTIME構造体を返します。

 

注意

なし。

 

関連

_Date_Time_SetSystemTime, $tagSYSTEMTIME

 


#include <GuiConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

; Vista では WindowsAPI "SetSystemTime" はシステムセキュリティによって拒否されることがある

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $tCur, $tNew

    ; GUIを作成
    $hGUI = GUICreate("Time", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 現在のシステム時間を取得
    $tCur = _Date_Time_GetSystemTime()
    MemoWrite("Current system date/time .: " & _Date_Time_SystemTimeToDateTimeStr($tCur))

    ; 新しいシステム時間を設定
    $tNew = _Date_Time_EncodeSystemTime(8, 19, @YEAR, 3, 10, 45)

    If Not _Date_Time_SetSystemTime(DllStructGetPtr($tNew)) Then
        MsgBox(4096, "Error", "System clock cannot be SET" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
        Exit
    EndIf

    $tNew = _Date_Time_GetSystemTime()
    MemoWrite("New system date/time .....: " & _Date_Time_SystemTimeToDateTimeStr($tNew))

    ; システム時間を復元
    _Date_Time_SetSystemTime(DllStructGetPtr($tCur))

    ; 現在のシステム時間を取得
    $tCur = _Date_Time_GetSystemTime()
    MemoWrite("Current system date/time .: " & _Date_Time_SystemTimeToDateTimeStr($tCur))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; メモコントロールに1行書き込む
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite