インセット値を取得します。
#Include <GDIPlus.au3>
_GDIPlus_ArrowCapGetMiddleInset($hArrowCap)
パラメータ
| $hArrowCap | ArrowCapオブジェクトのハンドル |
返し値
| 成功: | インセット値 |
| 失敗: | 0 |
注意
ミドルインセット値とは矢の根元がどれだけ矢先方向に移動するかを表す数値です。
関連
_GDIPlus_ArrowCapSetMiddleInset
こちらも参照
MSDNライブラリでGdipGetAdjustableArrowCapMiddleInsetを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hPen, $hEndCap, $iInset
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; リソースを作成
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hPen = _GDIPlus_PenCreate (0xFF000000, 4)
$hEndCap = _GDIPlus_ArrowCapCreate (3, 6)
; 矢印1を描画
$iInset = 0.5
_GDIPlus_ArrowCapSetMiddleInset ($hEndCap, $iInset)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 120, 390, 120, $hPen)
; 矢印2を描画
$iInset = _GDIPlus_ArrowCapGetMiddleInset ($hEndCap) + 0.5
_GDIPlus_ArrowCapSetMiddleInset ($hEndCap, $iInset)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
; 矢印3を描画
$iInset = _GDIPlus_ArrowCapGetMiddleInset ($hEndCap) + 0.5
_GDIPlus_ArrowCapSetMiddleInset ($hEndCap, $iInset)
_GDIPlus_PenSetCustomEndCap ($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine ($hGraphic, 10, 180, 390, 180, $hPen)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_ArrowCapDispose ($hEndCap)
_GDIPlus_PenDispose ($hPen)
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_Shutdown ()
EndFunc ;==>_Main