矢尻を塗りつぶすかどうかを設定します。
#Include <GDIPlus.au3>
_GDIPlus_ArrowCapSetFillState($hArrowCap, $bFilled = True)
パラメータ
$hArrowCap | ArrowCapオブジェクトのハンドル |
$bFilled | 塗りつぶし状態: True - 矢尻を塗りつぶします False - 矢尻を塗りつぶしません |
返し値
成功: | True |
失敗: | False |
注意
なし。
関連
_GDIPlus_ArrowCapGetFillState
こちらも参照
MSDNライブラリでGdipSetAdjustableArrowCapFillStateを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI, $hGraphic, $hPen, $hEndCap
; GUI作成
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState()
; リソースを作成
_GDIPlus_Startup ()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
$hPen = _GDIPlus_PenCreate (0xFF000000, 4)
$hEndCap = _GDIPlus_ArrowCapCreate (4, 6)
; 塗りつぶし状態を表示
MsgBox(4096, "Information", "Fill state: " & _GDIPlus_ArrowCapGetFillState($hEndCap))
; 矢印1を描画
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 130, 390, 130, $hPen)
; 矢印2を描画
_GDIPlus_ArrowCapSetFillState($hEndCap, False)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
_GDIPlus_GraphicsDrawLine($hGraphic, 10, 160, 390, 160, $hPen)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; リソースを破棄
_GDIPlus_ArrowCapDispose ($hEndCap)
_GDIPlus_PenDispose ($hPen)
_GDIPlus_GraphicsDispose ($hGraphic)
_GDIPlus_Shutdown ()
EndFunc ;==>_Main