Imageオブジェクトを描画します。
#Include <GDIPlus.au3>
_GDIPlus_GraphicsDrawImageRectRect($hGraphics, $hImage, $iSrcX, $iSrcY, $iSrcWidth, $iSrcHeight, $iDstX, $iDstY, $iDstWidth, $iDstHeight[, $iUnit = 2])
パラメータ
| $hGraphics | Graphicsオブジェクトのハンドル |
| $hImage | Imageオブジェクトのハンドル |
| $iSrcX | ソース画像の左上隅のX座標 |
| $iSrcY | ソース画像の左上隅のY座標 |
| $iSrcWidth | ソース画像の幅 |
| $iSrcHeight | ソース画像の高さ |
| $iDstX | 描画先画像の左上隅のX座標< |
| $iDstY | 描画先画像の左上隅のY座標 |
| $iDstWidth | 描画先画像の幅 |
| $iDstHeight | 描画先画像の高さ |
| $iUnit | [オプション]画像の計測単位を指定します |
返し値
| 成功: | True |
| 失敗: | False |
注意
なし。
関連
こちらも参照
MSDNライブラリでGdipDrawImageRectRectIを検索して下さい。
例
#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
Opt('MustDeclareVars', 1)
_Main()
Func _Main()
Local $hGUI1, $hGUI2, $hImage, $hGraphic1, $hGraphic2
; スクリーンの左上隅をキャプチャ
_ScreenCapture_Capture (@MyDocumentsDir & "\GDIPlus_Image.jpg", 0, 0, 400, 300)
; 元画像用のGUIを作成
$hGUI1 = GUICreate("Original", 400, 300, 0, 0)
GUISetState()
; ズーム画像用のGUIを作成
$hGUI2 = GUICreate("Zoomed", 400, 300, 0, 400)
GUISetState()
; GDI+ライブラリを初期化し、画像をロード
_GDIPlus_Startup ()
$hImage = _GDIPlus_ImageLoadFromFile (@MyDocumentsDir & "\GDIPlus_Image.jpg")
; 元画像を描画
$hGraphic1 = _GDIPlus_GraphicsCreateFromHWND ($hGUI1)
_GDIPlus_GraphicsDrawImage ($hGraphic1, $hImage, 0, 0)
; 2倍にズームした画像を描画
$hGraphic2 = _GDIPlus_GraphicsCreateFromHWND ($hGUI2)
_GDIPlus_GraphicsDrawImageRectRect ($hGraphic2, $hImage, 0, 0, 200, 200, 0, 0, 400, 300)
; リソースを解放
_GDIPlus_GraphicsDispose ($hGraphic1)
_GDIPlus_GraphicsDispose ($hGraphic2)
_GDIPlus_ImageDispose ($hImage)
_GDIPlus_Shutdown ()
; スクリーンショットファイルを削除
FileDelete(@MyDocumentsDir & "\GDIPlus_Image.jpg")
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main