Function Reference

_GDIPlus_GraphicsDrawString

文字列を描画します。

#Include <GDIPlus.au3>
_GDIPlus_GraphicsDrawString($hGraphics, $sString, $nX, $nY[, $sFont = "Arial"[, $fSize = 10[, $iFormat = 0]]])

 

パラメータ

$hGraphics Graphicsオブジェクトのハンドル
$sString 描画される文字列
$nX 文字列が描画される位置のX座標
$nY 文字列が描画される位置のY座標
$sFont [オプション]描画で使用されるフォント名
$fSize [オプション]描画で使用されるフォントサイズ
$iFormat [オプション]フォーマットフラグ。次の1つまたは組み合わせです:
0x0001 - 文字列方向を右から左に向かう方向に指定します
0x0002 - テキストの各行がディスプレイデバイス上で垂直方向に描画されるように指定します
0x0004 - 文字の一部が文字列のレイアウト長方形からはみ出ることを許可するよう指定します
0x0020 - Unicodeのレイアウト制御文字を表す文字が表示されるよう指定します
0x0400 - 要求されたフォントでサポートされていない文字で代わりのフォントを使用するよう指定します
0x0800 - 各行の末尾のスペースも文字列の長さに含めるよう指定します
0x1000 - テキストの次行への丸め込みを無効にするよう指定します
0x2000 - レイアウト長方形内におさまっている行のみ指定します
0x4000 - レイアウト長方形にからはみ出た文字、レイアウト長方形の外側に伸びるテキストも表示するよう指定します

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GDIPlus_GraphicsDrawStringEx

 


#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hGUI, $hGraphic

    ; GUI作成
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 文字列を描画
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    _GDIPlus_GraphicsDrawString ($hGraphic, "Hello world", 140, 110)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; リソースを破棄
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_Shutdown ()

EndFunc   ;==>_Main