Function Reference

_GDIPlus_PenGetAlignment

ペンの配置を取得します。

#Include <GDIPlus.au3>
_GDIPlus_PenGetAlignment($hPen)

 

パラメータ

$hPen Penオブジェクトのハンドル

 

返し値

成功: 配置の種類:
0 - ペンが描画される線の中心に配置されることを表します
1 - 多角形の描画の際、ペンが多角形の辺の内側に配置されることを表します
失敗: -1が返され@errorが設定されます

 

注意

なし。

 

関連

_GDIPlus_PenSetAlignment

 

こちらも参照

MSDNライブラリでGdipGetPenModeを検索して下さい。

 


#include <GuiConstantsEx.au3>
#include <GDIPlus.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen

    ; GUI作成
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; リソースを作成
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hPen = _GDIPlus_PenCreate (0xFF000000, 4)
    _GDIPlus_PenSetEndCap ($hPen, $GDIP_LINECAPARROWANCHOR)
    _GDIPlus_PenSetAlignment ($hPen, 1)

    ; ペンの配置を表示
    MsgBox(4096, "Information", "Pen alignment: " & _GDIPlus_PenGetAlignment ($hPen))

    ; 矢印を描画
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 130, 390, 130, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 6)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth ($hPen, 8)
    _GDIPlus_GraphicsDrawLine ($hGraphic, 10, 170, 390, 170, $hPen)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; リソースを破棄
    _GDIPlus_PenDispose ($hPen)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main