Function Reference

_GUICtrlAVI_Destroy

コントロールを削除します。

#Include <GuiAVI.au3>
_GUICtrlAVI_Destroy(ByRef $hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: True、ハンドルは0に設定されます
失敗: False

 

注意

_GUICtrlAVI_Createによって作成されたAVIコントロールにのみ使用できます。

 

関連

_GUICtrlAVI_Create

 


#include <GuiConstantsEx.au3>
#include <GuiAVI.au3>

Opt('MustDeclareVars', 1)

$Debug_AVI = False ; AVI関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $hAVI

_Main()

Func _Main()
    Local $Wow64 = ""
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $hGUI, $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"

    ; GUI作成
    $hGUI = GUICreate("(External) AVI Destroy", 300, 100)
    $hAVI = _GUICtrlAVI_Create ($hGUI, "", -1, 10, 10)
    GUISetState()

    ; サンプルのAutoIt AVIを再生
    _GUICtrlAVI_Open ($hAVI, $sFile)

    ; サンプルのAutoIt AVIを再生
    _GUICtrlAVI_Play($hAVI)

    Sleep(3000)

    ; 3秒後にAVIクリップを停止
    _GUICtrlAVI_Stop ($hAVI)

    ; AVIクリップを閉じる
    _GUICtrlAVI_Close ($hAVI)

    MsgBox(4160, "Information", "Destroy AVI Control")
    _GUICtrlAVI_Destroy ($hAVI)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE



    GUIDelete()
EndFunc   ;==>_Main