Function Reference

_GUICtrlComboBoxEx_GetItemIndent

アイテムがインデントされる画像幅数を取得します。

#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItemIndent($hWnd, $iIndex)

 

パラメータ

$hWnd コントロールのハンドル
$iIndex ゼロ始まりのアイテムのインデックス

 

返し値

成功: アイテムのインデント

 

注意

なし。

 

関連

_GUICtrlComboBoxEx_SetItemIndent

 


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hGUI, $hImage, $image, $hCombo
   
    ; GUIを作成
    $hGUI = GUICreate("ComboBoxEx Get Item Indent", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    GUISetState()

    $hImage = _GUIImageList_Create (16, 16, 5, 3)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon ($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add ($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap ($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList ($hCombo, $hImage)

    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    For $x = 0 To 149
        $image = Random(0, 8, 1)
        _GUICtrlComboBoxEx_AddString ($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $image, $image)
    Next
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)
    _GUICtrlComboBoxEx_SetItemImage ($hCombo, 0, 1)
    _GUICtrlComboBoxEx_SetItemIndent ($hCombo, 1, 1)
    _GUICtrlComboBoxEx_SetItemIndent ($hCombo, 2, 1)
    MsgBox(4160, "Information", "Item Indent: " & _GUICtrlComboBoxEx_GetItemIndent ($hCombo, 2))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main