Function Reference

_GUICtrlComboBoxEx_LimitText

ユーザーがコンボボックスのエディットコントロールに入力できるテキストの長さを制限します。

#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_LimitText($hWnd[, $iLimit = 0])

 

パラメータ

$hWnd コントロールのハンドル
$iLimit [オプション]テキストの最大長

 

返し値

なし。

 

注意

$iLimitパラメータがゼロの場合、テキストの長さは0x7FFFFFFE文字に制限されます。

コンボボックスに$CBS_AUTOHSCROLLスタイルが設定されていない場合、
エディットコントロールのサイズより大きいテキスト制限設定は反映されません。

_GUICtrlComboBox_LimitText関数はユーザーが入力するテキストのみ制限します。
メッセージが送信された際に既にエディットコントロールに設定されているテキスト、
リストボックス内のテキストが選択された際にエディットコントロールにコピーされるテキストには反映されません。

ユーザーがエディットコントロール入力するテキストに対するデフォルトの制限値は30,000文字です。

 

関連

 


#include <GuiComboBoxEx.au3>
#include <GuiConstantsEx.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hGUI, $hCombo
   
    ; GUIを作成
    $hGUI = GUICreate("ComboBoxEx Limit Text", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    GUISetState()

    ; ファイルを追加
    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    _GUICtrlComboBoxEx_AddDir ($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBoxEx_AddDir ($hCombo, "", $DDL_DRIVES)
    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    _GUICtrlComboBoxEx_AddDir ($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    ; エディットコントロールのテキストを制限
    _GUICtrlComboBoxEx_LimitText ($hCombo, 10)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main