Function Reference

_GUICtrlComboBox_GetCueBanner

コンボボックスのエディットコントロールに表示されるキューバナーテキストを取得します。

#Include <GuiComboBox.au3>
_GUICtrlComboBox_GetCueBanner($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: キューバナーテキスト
失敗: ""

 

注意

キューバナーとは選択されているものがない場合にコンボボックスのエディットコントロールに表示されるテキストです。

必須OS: Windows Vista以降

 

関連

_GUICtrlComboBox_SetCueBanner

 


#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo
_Main()

Func _Main()
    Local $hCombo

    ; GUIを作成
    GUICreate("ComboBox Get Count", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    _GUICtrlComboBox_SetCueBanner($hCombo, "Select an Item")
    $iMemo = GUICtrlCreateEdit("", 10, 50, 376, 234, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; ファイルを追加
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)
   
    MemoWrite("Cue Banner: " & _GUICtrlComboBox_GetCueBanner($hCombo))
   
    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite