Function Reference

_GUICtrlComboBox_GetMinVisible

コンボボックスのドロップダウンリストで表示されるアイテムの最小数を取得します。

#Include <GuiComboBox.au3>
_GUICtrlComboBox_GetMinVisible($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: True
失敗: False

 

注意

ドロップダウンリストのアイテム数が最小値よりも大きい場合、コンボボックスにスクロールバーが使用されます。

コンボボックスに$CBS_NOINTEGRALHEIGHTスタイルが設定されている場合、この関数は無視されます。

 

関連

_GUICtrlComboBox_SetMinVisible

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hCombo

    ; GUIを作成
    GUICreate("ComboBox Get Min Visible", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; ファイルを追加
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 表示数の最小値を取得
    MsgBox(4160, "Information", "Min Visible:" & @TAB & _GUICtrlComboBox_GetMinVisible($hCombo), 3)

    ; ドロップダウンを表示
    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)

    ; 表示数の最小値を設定
    _GUICtrlComboBox_SetMinVisible($hCombo, 50)

    ; ドロップダウンを表示
    _GUICtrlComboBox_ShowDropDown($hCombo)

    Sleep(500)

    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)
   
    ; 表示数の最小値を取得
    MsgBox(4160, "Information", "Min Visible:" & @TAB & _GUICtrlComboBox_GetMinVisible($hCombo), 3)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main