Function Reference

_GUICtrlComboBox_LimitText

ユーザーがコンボボックスのエディットコントロールに入力できるテキストの長さを制限します。

#Include <GuiComboBox.au3>
_GUICtrlComboBox_LimitText($hWnd[, $iLimit = 0])

 

パラメータ

$hWnd コントロールのハンドル
$iLimit [オプション]テキストの最大長

 

返し値

なし。

 

注意

$iLimitパラメータがゼロの場合、テキストの長さは0x7FFFFFFE文字に制限されます。

コンボボックスに$CBS_AUTOHSCROLLスタイルが設定されていない場合、
エディットコントロールのサイズより大きいテキスト制限設定は反映されません。

_GUICtrlComboBox_LimitText関数はユーザーが入力するテキストのみ制限します。
メッセージが送信された際に既にエディットコントロールに設定されているテキスト、
リストボックス内のテキストが選択された際にエディットコントロールにコピーされるテキストには反映されません。

ユーザーがエディットコントロール入力するテキストに対するデフォルトの制限値は30,000文字です。

 

関連

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

$Debug_CB = False ; ComboBox/ComboBoxEx関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hCombo

    ; GUIを作成
    GUICreate("ComboBox Limit Text", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; エディットコントロールのテキストを制限
    _GUICtrlComboBox_LimitText($hCombo, 10)
   
    ; ファイルを追加
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)
   
    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main