Function Reference

_GUICtrlEdit_GetRECT

エディットコントロールのフォーマット済み長方形を取得します。

#Include <GuiEdit.au3>
_GUICtrlEdit_GetRECT($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: 次のフォーマットの長方形を格納している配列:
    [0] - 長方形の左上隅のX座標
    [1] - 長方形の左上隅のY座標
    [2] - 長方形の右下隅のX座標
    [3] - 長方形の右下隅のY座標

 

注意

特定の状況下では、_GUICtrlEdit_GetRECTは_GUICtrlEdit_SetRECTが設定した正確な値を返しません。
値は近似値で、誤差は数ピクセルです。

 

関連

_GUICtrlEdit_GetRECTEx

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_Ed = False ; Edit関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $StatusBar, $hEdit, $hGUI
    Local $Wow64 = ""
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"
    Local $aPartRightSide[6] = [50, 130, 210, 290, 378, -1], $aRect

    ; GUI作成
    $hGUI = GUICreate("Edit Get RECT", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $StatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($StatusBar, 5, 97, "shell32.dll")
    _GUICtrlStatusBar_SetText($StatusBar, "Rect")
    GUISetState()

    ; 長方形を取得
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    $aRect[0] += 10
    $aRect[1] += 10
    $aRect[2] -= 10
    $aRect[3] -= 10

    ; 長方形を設定
    _GUICtrlEdit_SetRECT($hEdit, $aRect)

    ; テキストを追加
    _GUICtrlEdit_AppendText($hEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($hEdit, 0, _GUICtrlEdit_GetLineCount($hEdit) * - 1)

    ; 長方形を取得
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    _GUICtrlStatusBar_SetText($StatusBar, "Left: " & $aRect[0], 1)
    _GUICtrlStatusBar_SetText($StatusBar, "Topt: " & $aRect[1], 2)
    _GUICtrlStatusBar_SetText($StatusBar, "Right: " & $aRect[2], 3)
    _GUICtrlStatusBar_SetText($StatusBar, "Bottom: " & $aRect[3], 4)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main