Function Reference

_GUICtrlEdit_SetMargins

左余白と右余白の幅を設定します。

#Include <GuiEdit.au3>
_GUICtrlEdit_SetMargins($hWnd[, $iMargin = 0x1[, $iLeft = 0xFFFF[, $iRight = 0xFFFF]]])

 

パラメータ

$hWnd コントロールのハンドル
$iMargin [オプション]次の1つまたは複数です
$EC_LEFTMARGIN - 左余白を設定します
$EC_RIGHTMARGIN - 右余白を設定します
デフォルト: $EC_LEFTMARGIN
$iLeft [オプション]左余白の新しい幅
デフォルト: $EC_USEFONTINFO
$iRight [オプション]右余白の新しい幅
デフォルト: $EC_USEFONTINFO

 

返し値

次のフォーマットの配列を返します:
[0] - 左余白の幅
[1] - 右余白の幅

 

 

注意

なし。

 

関連

_GUICtrlEdit_GetMargins

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

$Debug_Ed = False ; Edit関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $StatusBar, $hEdit, $hGUI
    Local $Wow64 = ""
    If @AutoItX64 Then $Wow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\changelog.txt"
    Local $aPartRightSide[3] = [190, 378, -1], $aMargins

    ; GUI作成
    $hGUI = GUICreate("Edit Set Margins", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $StatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($StatusBar, 2, 97, "shell32.dll")
    GUISetState()

    ; 余白を設定
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; テキストを設定
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; 余白を取得
    $aMargins = _GUICtrlEdit_GetMargins($hEdit)
    _GUICtrlStatusBar_SetText($StatusBar, "Left Margin: " & $aMargins[0])
    _GUICtrlStatusBar_SetText($StatusBar, "Right Margin: " & $aMargins[1], 1)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main