Function Reference

_GUICtrlHeader_GetOrderArray

ヘッダーコントロールアイテムの現在の左から右への並び順を取得します。

#Include <GuiHeader.au3>
_GUICtrlHeader_GetOrderArray($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: 次のフォーマットの配列:
        [0] - 配列内のアイテム数
        [1] - アイテム番号1
        [2] - アイテム番号2
        [n] - アイテム番号n

 

注意

なし。

 

関連

_GUICtrlHeader_SetOrderArray

 


#include <GuiConstantsEx.au3>
#include <GuiHeader.au3>

Opt('MustDeclareVars', 1)

$Debug_HDR = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader, $aOrder[5] = [4, 3, 1, 2, 0]

    ; GUIを作成
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create ($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 列を追加
    _GUICtrlHeader_AddItem ($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Column 4", 100)

    ; 並び順の配列を設定
    _GUICtrlHeader_SetOrderArray ($hHeader, $aOrder)

    ; 並び順の配列を表示
    $aOrder = _GUICtrlHeader_GetOrderArray ($hHeader)
    For $iI = 0 To $aOrder[0]
        MemoWrite("Order " & $iI & ": " & $aOrder[$iI])
    Next

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite