Function Reference

_GUICtrlHeader_SetItemAlign

アイテムのテキスト配置を設定します。

#Include <GuiHeader.au3>
_GUICtrlHeader_SetItemAlign($hWnd, $iIndex, $iAlign)

 

パラメータ

$hWnd コントロールのハンドル
$iIndex ゼロ始まりのアイテムインデックス
$iAlign テキスト配置:
0 - テキスト左揃え
1 - テキスト右揃え
2 - テキスト中央揃え

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GUICtrlHeader_GetItemAlign

 


#include <GuiConstantsEx.au3>
#include <GuiHeader.au3>

Opt('MustDeclareVars', 1)

$Debug_HDR = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader

    ; GUIを作成
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create ($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 列を追加
    _GUICtrlHeader_AddItem ($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem ($hHeader, "Column 4", 100)

    ; 列1の配置をリセット
    _GUICtrlHeader_SetItemAlign ($hHeader, 0, 2)

    ; 列1の配置を表示
    MemoWrite("Column 1 alignment: " & _GUICtrlHeader_GetItemAlign ($hHeader, 0))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite