GUI IPアドレスコントロールを作成します。
#Include <GuiIPAddress.au3>
_GUICtrlIpAddress_Create($hWnd, $iX, $iY[, $iWidth = 125[, $iHeight = 25[, $iStyles = 0x00000000[, $iExstyles = 0x00000000]]]])
パラメータ
| $hWnd | 親ウィンドウまたはオーナーウィンドウのハンドル |
| $iX | コントロールの水平位置 |
| $iY | コントロールの垂直位置 |
| $iWidth | [オプション]コントロールの幅 |
| $iHeight | [オプション]コントロールの高さ |
| $iStyle | [オプション]コントロールスタイル: 強制 : $WS_CHILD、$WS_VISIBLE、$WS_TABSTOP |
| $iExStyle | [オプション]拡張コントロールスタイル |
返し値
| 成功: | IPアドレスコントロールのハンドル |
| 失敗: | 0 |
注意
なし。
関連
_GUICtrlIpAddress_Destroy
例
#include <GuiConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>
Opt("MustDeclareVars", 1)
$Debug_IP = False ; IPAddress関数に渡されるClassNameを調べる。Trueを設定すると動作確認のために他のコントロールのハンドルを使用
Global $hIPAddress
_Main()
Func _Main()
Local $hgui
$hgui = GUICreate("IP address control Create Example", 400, 300)
$hIPAddress = _GUICtrlIpAddress_Create ($hgui, 10, 10)
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
_GUICtrlIpAddress_Set ($hIPAddress, "24.168.2.128")
; ユーザーがGUIを閉じるまで待機
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR
Local $tInfo
$tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
$iCode = DllStructGetData($tNMHDR, "Code")
Switch $hWndFrom
Case $hIPAddress
Switch $iCode
Case $IPN_FIELDCHANGED ; ユーザーがコントロールフィールドを変更、またはあるフィールドを他へ移動させるた際に送信
$tInfo = DllStructCreate($tagNMIPADDRESS, $ilParam)
_DebugPrint("$IPN_FIELDCHANGED" & @LF & "--> hWndFrom:" & @TAB & DllStructGetData($tInfo, "hWndFrom") & @LF & _
"-->IDFrom:" & @TAB & DllStructGetData($tInfo, "IDFrom") & @LF & _
"-->Code:" & @TAB & DllStructGetData($tInfo, "Code") & @LF & _
"-->Field:" & @TAB & DllStructGetData($tInfo, "Field") & @LF & _
"-->Value:" & @TAB & DllStructGetData($tInfo, "Value"))
; 返し値は無視される
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_NOTIFY
Func _DebugPrint($s_text, $line = @ScriptLineNumber)
ConsoleWrite( _
"!===========================================================" & @LF & _
"+======================================================" & @LF & _
"-->Line(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
"+======================================================" & @LF)
EndFunc ;==>_DebugPrint