Function Reference

_GUICtrlIpAddress_SetEx

IPアドレスコントロールにアドレスを設定します。

#Include <GuiIPAddress.au3>
_GUICtrlIpAddress_SetEx($hWnd, $tIP)

 

パラメータ

$hWnd コントロールのハンドル
$tIP コントロール用の新しいIPアドレスを格納した$tagGetIPAddress構造体

 

返し値

なし。

 

注意

なし。

 

関連

_GUICtrlIpAddress_GetEx, $tagGetIPAddress

 


#include <GuiConstantsEx.au3>
#include <GuiIPAddress.au3>

Opt("MustDeclareVars", 1)

$Debug_IP = False ; IPAddress関数に渡されるClassNameを調べる。Trueを設定すると動作確認のために他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $hgui, $tIP = DllStructCreate($tagGetIPAddress), $aIP[4] = [24, 168, 2, 128], $hIPAddress
   
    $hgui = GUICreate("IP address control SetEx Example", 400, 300)
    $hIPAddress = _GUICtrlIpAddress_Create ($hgui, 2, 4, 125, 20)
    $iMemo = GUICtrlCreateEdit("", 2, 28, 396, 270, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)
   
    For $x = 0 To 3
        DllStructSetData($tIP, "Field" & $x + 1, $aIP[$x])
    Next
   
    _GUICtrlIpAddress_SetEx ($hIPAddress, $tIP)

    $tIP = _GUICtrlIpAddress_GetEx ($hIPAddress)

    For $x = 0 To 3
        MemoWrite("Field " & $x + 1 & " .....: " & DllStructGetData($tIP, "Field" & $x + 1))
    Next

    ; ユーザーがGUIを閉じるまで待機
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite