ディレクトリとファイルの名前を追加します。
#Include <GuiListBox.au3>
_GUICtrlListBox_Dir($hWnd, $sFile[, $iAttributes = 0[, $fBrackets = True]])
パラメータ
| $hWnd | コントロールのハンドル |
| $sFile | 絶対パス、相対パスまたはファイル名をを指定します |
| $iAttributes | [オプション]追加されるファイルまたはディレクトリの属性を指定します: $DDL_READWRITE - 読み取り属性、書き込み属性のみ $DDL_READONLY - 読み取り属性のみ $DDL_HIDDEN - 隠しファイル属性 $DDL_SYSTEM - システムファイル属性 $DDL_DIRECTORY - サブディレクトリ属性 $DDL_ARCHIVE - アーカイブファイル属性 $DDL_DRIVES - マッピングされているずべてのドライブをリストに追加 $DDL_EXCLUSIVE - 指定された属性のファイルのみ追加 |
| $fBrackets | [オプション]$DDL_DRIVESが使用された際のインクルード/エクスクルードのカッコ |
返し値
| 成功: | 最後に追加された名前のゼロ始まりのインデックス |
| 失敗: | -1 |
注意
新しい文字列を保持するための十分なスペースがない場合、返し値は$LB_ERRSPACEになります。
関連
_GUICtrlListBox_InitStorage
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIListBox.au3>
#include <GuiConstantsEx.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_LB = False ; ListBox関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $hListBox
; GUIを作成
GUICreate("List Box Dir", 400, 296)
$hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
GUISetState()
; ファイルを追加
_GUICtrlListBox_BeginUpdate($hListBox)
_GUICtrlListBox_ResetContent($hListBox)
_GUICtrlListBox_InitStorage($hListBox, 100, 4096)
_GUICtrlListBox_Dir($hListBox, @WindowsDir & "\win*.exe")
_GUICtrlListBox_AddFile($hListBox, @WindowsDir & "\Notepad.exe")
_GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES)
_GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES, False)
_GUICtrlListBox_EndUpdate($hListBox)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main