Function Reference

_GUICtrlListView_AddItem

リストの末尾に新しいアイテムを追加します。

#Include <GuiListView.au3>
_GUICtrlListView_AddItem($hWnd, $sText[, $iImage = -1[, $iParam = 0]])

 

パラメータ

$hWnd コントロールのハンドル
$sText アイテムのテキスト。-1に設定した場合、アイテム設定は$LVN_GETDISPINFO通知メッセージを通じて設定されます。
$iImage [オプション]コントロールの画像リスト内でのアイテムアイコンのゼロ始まりのインデックス
$iParam [オプション]アプリケーション定義のデータ

 

返し値

成功: 新しいアイテムのインデックス
失敗: -1

 

注意

この関数を使用してサブアイテムを挿入することはできません。
サブアイテムを挿入するには_GUICtrlListView_AddSubItemを使用して下さい。

 

関連

_GUICtrlListView_AddSubItem

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $hImage, $hListView

    ; GUIを作成
    GUICreate("ListView Add Item", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetUnicodeFormat($hListView, False)
    GUISetState()

    ; 画像をロード
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; 列を追加
    _GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
    _GUICtrlListView_InsertColumn($hListView, 1, "Column 2", 100)
    _GUICtrlListView_InsertColumn($hListView, 2, "Column 3", 100)

    ; アイテムを追加
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)


    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main