指定された数のアイテムを表示するのに必要なおおよその幅を計算します。
#Include <GuiListView.au3>
_GUICtrlListView_ApproximateViewWidth($hWnd[, $iCount = -1[, $iCX = -1[, $iCY = -1]]])
パラメータ
| $hWnd | コントロールのハンドル |
| $iCount | [オプション]コントロールに表示されるアイテムの数。 このパラメータが-1の場合、コントロール内のアイテム総数が使用されます。 |
| $iCX | [オプション]コントロールのX方向の長さをピクセル単位で表します。 このパラメータを-1にすると現在の幅の値が使用されます。 |
| $iCY | [オプション]コントロールのY方向の長さをピクセル単位で表します。 このパラメータを-1にすると現在の高さの値が使用されます。 |
返し値
アイテムを表示するのに必要なおおよそのピクセル単位での幅を返します。
注意
この命令で指定されたコントロールのサイズ設定は再描画を最適化し、ちらつきを抑えるのに使用されます。
関連
_GUICtrlListView_ApproximateViewHeight, _GUICtrlListView_ApproximateViewRect
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <Constants.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $iX, $hListView
GUICreate("ListView Approximate View Width", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_SetUnicodeFormat($hListView, False)
GUISetState()
; 列を追加
_GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
; アイテムを追加
For $iI = 0 To 9
_GUICtrlListView_AddItem($hListView, "Row " & $iI)
Next
MsgBox(4096, "Information", "Approximate View Width")
; 表示幅を変更
$iX = _GUICtrlListView_ApproximateViewWidth($hListView)
_WinAPI_SetWindowPos(GUICtrlGetHandle($hListView), 0, 2, 2, $iX, 268, $SWP_NOZORDER)
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main