Function Reference

_GUICtrlListView_DeleteItemsSelected

選択されているアイテムを削除します。

#Include <GuiListView.au3>
_GUICtrlListView_DeleteItemsSelected($hWnd)

 

パラメータ

$hWnd コントロールのコントロールID/ハンドル

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GUICtrlListView_DeleteItem, _GUICtrlListView_DeleteAllItems

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Example1()
Example2()
Example_UDF_Created()

Func Example1()
    Local $aItems[10][3], $hListView
   
    GUICreate("ListView Delete Items Selected", 400, 300)
    $hListView = GUICtrlCreateListView("col1|col2|col3", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState()
   
    ; 3列ロード
    For $iI = 0 To 9
        GUICtrlCreateListViewItem("Item " & $iI & "|Item " & $iI & "-1|Item " & $iI & "-2", $hListView)
    Next
   
    _GUICtrlListView_SetItemSelected($hListView, Random(0, UBound($aItems) - 1, 1))
   
    MsgBox(4160, "Information", "Delete Item Selected")
    ; UDF関数を使用して作成したアイテム。コントロールのハンドルを渡す
    MsgBox(4160, "Deleted?", _GUICtrlListView_DeleteItemsSelected($hListView))
   
    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example1

Func Example2()
    Local $aItems[10][3], $hListView
   
    GUICreate("ListView Delete Items Selected", 400, 300)
    $hListView = GUICtrlCreateListView("col1|col2|col3", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState()
   
    ; 3列ロード
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Item " & $iI
        $aItems[$iI][1] = "Item " & $iI & "-1"
        $aItems[$iI][2] = "Item " & $iI & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)
   
    _GUICtrlListView_SetItemSelected($hListView, Random(0, UBound($aItems) - 1, 1))
   
    MsgBox(4160, "Information", "Delete Item Selected")
    ; UDF関数を使用して作成したアイテム。コントロールのハンドルを渡す
    MsgBox(4160, "Deleted?", _GUICtrlListView_DeleteItemsSelected(GUICtrlGetHandle($hListView)))
   
    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example2

Func Example_UDF_Created()
    Local $GUI, $aItems[10][3], $hListView
   
    $GUI = GUICreate("(UDF Created) ListView Delete Items Selected", 400, 300)
    $hListView = _GUICtrlListView_Create($GUI, "col1|col2|col3", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState()
   
    ; 3列ロード
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Item " & $iI
        $aItems[$iI][1] = "Item " & $iI & "-1"
        $aItems[$iI][2] = "Item " & $iI & "-2"
    Next

    _GUICtrlListView_AddArray($hListView, $aItems)
   
    _GUICtrlListView_SetItemSelected($hListView, Random(0, UBound($aItems) - 1, 1))
   
    MsgBox(4160, "Information", "Delete Item Selected")
    ; 既にハンドル
    MsgBox(4160, "Deleted?", _GUICtrlListView_DeleteItemsSelected($hListView))
   
    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example_UDF_Created