Function Reference

_GUICtrlListView_GetOutlineColor

コントロールの境界線の色を取得します。

#Include <GuiListView.au3>
_GUICtrlListView_GetOutlineColor($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

コントロールの境界線の色を返します。

 

注意

必須OS:Windows XP以降

コントロールには$LVS_EX_BORDERSELECT拡張ウィンドウスタイルが設定されている必要があります。

 

関連

_GUICtrlListView_SetOutlineColor

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()
    Local $iX, $iY, $hImage, $hListView
   
    GUICreate("ListView Get Outline Color", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($hListView, $LVS_ICON)
    ; 拡張コントロールスタイルを有効化
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_BORDERSELECT)
    GUISetState()

    ; 画像をロード
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 0)

    ; 列を追加
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; アイテムを追加
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

    ; 輪郭線色を設定
    _GUICtrlListView_SetOutlineColor($hListView, 0x0000FF)
    MsgBox(4160, "Information", "Outline Color: " & Hex(_GUICtrlListView_GetOutlineColor($hListView)))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main