グループ情報を設定します。
#Include <GuiListView.au3>
_GUICtrlListView_SetGroupInfo($hWnd, $iGroupID, $sHeader[, $iAlign = 0[, $iState = $LVGS_NORMAL]])
パラメータ
$hWnd | コントロールのハンドル |
$iGroupID | グループのID |
$sHeader | ヘッダーテキスト |
$iAlign | [オプション]グループのヘッダーテキストの配置 0 - 左 1 - 中央 2 - 右 |
$iState | [オプション]Vista以降では次の値のいずれかを設定できます: $LVGS_NORMAL - グループが展開され、グループ名とグループ内の全てのアイテムが表示されます。 $LVGS_COLLAPSED - グループが閉じられます。 $LVGS_HIDDEN - グループを非表示にします。 $LVGS_NOHEADER - グループでヘッダーが表示されません。 $LVGS_COLLAPSIBLE - グループを閉じることができるようになります。 $LVGS_FOCUSED - グループにキーボードフォーカスが合います。 $LVGS_SELECTED - グループが選択されます。 $LVGS_SUBSETED - グループでアイテムの一部のみが表示されます。 $LVGS_SUBSETLINKFOCUSED - グループのサブセットリンクにキーボードフォーカスが合います。 |
返し値
成功: | True |
失敗: | False |
注意
必須OS:Windows XP以降
関連
_GUICtrlListView_GetGroupInfo, _GUICtrlListView_GetGroupInfoByIndex
例
#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
Opt('MustDeclareVars', 1)
$Debug_LV = False ; ListView関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
_Main()
Func _Main()
Local $aInfo, $hImage, $hListView
GUICreate("ListView Set Group Info", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
; 画像をロード
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)
; 列を追加
_GUICtrlListView_AddColumn($hListView, "Column 1", 100)
_GUICtrlListView_AddColumn($hListView, "Column 2", 100)
_GUICtrlListView_AddColumn($hListView, "Column 3", 100)
; アイテムを追加
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)
; グループを作成
_GUICtrlListView_EnableGroupView($hListView)
_GUICtrlListView_InsertGroup($hListView, -1, 1, "Group 1", 1)
_GUICtrlListView_InsertGroup($hListView, -1, 2, "Group 2")
_GUICtrlListView_SetItemGroupID($hListView, 0, 1)
_GUICtrlListView_SetItemGroupID($hListView, 1, 2)
_GUICtrlListView_SetItemGroupID($hListView, 2, 2)
; グループ情報を変更
$aInfo = _GUICtrlListView_GetGroupInfo($hListView, 1)
MsgBox(4160, "Information", "Group 1 Text: " & $aInfo[0])
_GUICtrlListView_SetGroupInfo($hListView, 1, "New Group 1")
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main