Function Reference

_GUICtrlMenu_AddMenuItem

メニューの終端に新しいメニューアイテムを追加します。

#Include <GuiMenu.au3>
_GUICtrlMenu_AddMenuItem($hMenu, $sText[, $iCmdID = 0[, $hSubMenu = 0]])

 

パラメータ

$hMenu メニューのハンドル
$sText メニューアイテムのテキスト。空白の場合、セパレータが追加されます。
$iCmdID [オプション]アイテムに割り当てられるコマンドID
$hSubMenu [オプション]メニューアイテムに関連付けられたサブメニューのハンドル

 

返し値

成功: ゼロ始まりのメニューアイテムのインデックス
失敗: -1

 

注意

なし。

 

関連

_GUICtrlMenu_InsertMenuItem

 


#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; GUIを作成
    $hGUI = GUICreate("Menu", 400, 300)

    ; ファイルメニューを作成
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_AddMenuItem ($hFile, "&New", $idNew)
    _GUICtrlMenu_AddMenuItem ($hFile, "&Open", $idOpen)
    _GUICtrlMenu_AddMenuItem ($hFile, "&Save", $idSave)
    _GUICtrlMenu_AddMenuItem ($hFile, "", 0)
    _GUICtrlMenu_AddMenuItem ($hFile, "E&xit", $idExit)

    ; 編集メニューを作成
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_AddMenuItem ($hEdit, "&Cut", $idCut)
    _GUICtrlMenu_AddMenuItem ($hEdit, "C&opy", $idCopy)
    _GUICtrlMenu_AddMenuItem ($hEdit, "&Paste", $idPaste)

    ; ヘルプメニューを作成
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_AddMenuItem ($hHelp, "&About", $idAbout)

    ; メインメニューを作成
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_AddMenuItem ($hMain, "&File", 0, $hFile)
    _GUICtrlMenu_AddMenuItem ($hMain, "&Edit", 0, $hEdit)
    _GUICtrlMenu_AddMenuItem ($hMain, "&Help", 0, $hHelp)

    ; ウィンドウにメニューを設定
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)
    GUISetState()

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main