Function Reference

_GUICtrlMenu_CheckRadioItem

指定されたメニューアイテムをチェックし、それをラジオアイテムにします。

#Include <GuiMenu.au3>
_GUICtrlMenu_CheckRadioItem($hMenu, $iFirst, $iLast, $iCheck[, $fByPos = True])

 

パラメータ

$hMenu メニューのハンドル
$iFirst グループ内の最初のメニューアイテムの識別子または位置
$iLast グループ内の最後のメニューアイテムの識別子または位置
$iCheck チェックするメニューアイテムの識別子または位置
$fByPos [オプション]メニュー識別子フラグ:
 True - $iFirst、$iLast、$iCheckはゼロ始まりのアイテム位置です
False - $iFirst、$iLast、$iCheckはメニューアイテムの識別子です

 

返し値

成功: True
失敗: False

 

注意

この関数は$iCheckで指定されたアイテムに$MFT_RADIOCHECKフラグと$MFS_CHECKEDフラグを設定し、グループ内の他の全てのアイテムの両フラグを解除します。
チェックされたアイテムはチェックマークのビットマップの代わりに黒丸のビットマップを使用して描画されます。

 

関連

_GUICtrlMenu_CheckMenuItem

 

こちらも参照

MSDNライブラリでCheckMenuRadioItemを検索して下さい。

 


#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; GUIを作成
    $hGUI = GUICreate("Menu", 400, 300)

    ; ファイルメニューを作成
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
    _GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
    _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)

    ; 編集メニューを作成
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)

    ; ヘルプメニューを作成
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)

    ; メインメニューを作成
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)

    ; ウィンドウにメニューを設定
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)
    GUISetState()

    ; "開く"メニューアイテムをチェック
    _GUICtrlMenu_CheckRadioItem ($hFile, 0, 4, 2)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main