Function Reference

_GUICtrlMenu_GetMenu

指定されたウィンドウに割り当てられているメニューのハンドルを取得します。

#Include <GuiMenu.au3>
_GUICtrlMenu_GetMenu($hWnd)

 

パラメータ

$hWnd メニューハンドルを取得するウィンドウの識別子

 

返し値

成功: メニューのハンドル
失敗: 0

 

注意

_GUICtrlMenu_GetMenuはフローティングメニューバーに対しては動作しません。
フローティングメニューバーは標準メニューを模したカスタムコントロールであり、メニューではありません。

 

関連

_GUICtrlMenu_SetMenu, _GUICtrlMenu_FindParent

 

こちらも参照

MSDNライブラリでGetMenuを検索して下さい。

 


#include <GuiMenu.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hWnd, $hMain, $hItem1, $hItem2

    ; メモ帳を開く
    Run("Notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    ; サブアイテムメニューを作成
    $hItem1 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hItem1, 0, "SubItem &1", 0x1000)
    _GUICtrlMenu_InsertMenuItem($hItem1, 1, "SubItem &2", 0x1001)

    ; メニューを作成
    $hItem2 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hItem2, 0, "Item &1", 0x2000, $hItem1)
    _GUICtrlMenu_InsertMenuItem($hItem2, 1, "Item &2", 0x2001)
    _GUICtrlMenu_InsertMenuItem($hItem2, 2, "", 0)
    _GUICtrlMenu_InsertMenuItem($hItem2, 3, "Item &3", 0x2002)
    _GUICtrlMenu_InsertMenuItem($hItem2, 4, "Item &4", 0x2003)

    ; メモ帳に新しいメニューを挿入
    _GUICtrlMenu_InsertMenuItem($hMain, 6, "&AutoIt", 0, $hItem2)
    _GUICtrlMenu_DrawMenuBar($hWnd)

EndFunc   ;==>_Main