Function Reference

_GUICtrlMenu_InsertMenuItemEx

新しいメニューアイテムをメニューの指定された位置に挿入します。

#Include <GuiMenu.au3>
_GUICtrlMenu_InsertMenuItemEx($hMenu, $iIndex, ByRef $tMenu[, $fByPos = True])

 

パラメータ

$hMenu メニューのハンドル
$iIndex 新しいアイテムを挿入する1つ前のメニューアイテムの位置
$tMenu $tagMENUITEMINFO構造体
$fByPos [オプション]メニュー識別子フラグ:
 True - $iIndexはゼロ始まりのアイテムの位置です
False - $iIndexはメニューアイテムの識別子です

 

返し値

成功: True
失敗: False

 

注意

なし。

 

関連

_GUICtrlMenu_InsertMenuItem, $tagMENUITEMINFO

 

こちらも参照

MSDNライブラリでInsertMenuItemを検索して下さい。

 


#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; GUIを作成
    $hGUI = GUICreate("Menu", 400, 300)

    ; ファイルメニューを作成
    $hFile = _GUICtrlMenu_CreateMenu ()
    InsertItem($hFile, 0, "&New", $idNew)
    InsertItem($hFile, 1, "&Open", $idOpen)
    InsertItem($hFile, 2, "&Save", $idSave)
    InsertItem($hFile, 3, "", 0)
    InsertItem($hFile, 4, "E&xit", $idExit)

    ; 編集メニューを作成
    $hEdit = _GUICtrlMenu_CreateMenu ()
    InsertItem($hEdit, 0, "&Cut", $idCut)
    InsertItem($hEdit, 1, "C&opy", $idCopy)
    InsertItem($hEdit, 2, "&Paste", $idPaste)

    ; ヘルプメニューを作成
    $hHelp = _GUICtrlMenu_CreateMenu ()
    InsertItem($hHelp, 0, "&About", $idAbout)

    ; メインメニューを作成
    $hMain = _GUICtrlMenu_CreateMenu ()
    InsertItem($hMain, 0, "&File", 0, $hFile)
    InsertItem($hMain, 1, "&Edit", 0, $hEdit)
    InsertItem($hMain, 2, "&Help", 0, $hHelp)

    ; ウィンドウにメニューを設定
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)
    GUISetState()

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メニューアイテムを挿入(難しい方法)
Func InsertItem($hMenu, $iIndex, $sText, $iCmdID = 0, $hSubMenu = 0)
    Local $tMenu, $tText, $aResult

    $tMenu = DllStructCreate($tagMENUITEMINFO)
    DllStructSetData($tMenu, "Size", DllStructGetSize($tMenu))
    DllStructSetData($tMenu, "Mask", BitOR($MIIM_ID, $MIIM_STRING, $MIIM_SUBMENU))
    DllStructSetData($tMenu, "ID", $iCmdID)
    DllStructSetData($tMenu, "SubMenu", $hSubMenu)
    If $sText = "" Then
        DllStructSetData($tMenu, "Mask", $MIIM_FTYPE)
        DllStructSetData($tMenu, "Type", $MFT_SEPARATOR)
    Else
        DllStructSetData($tMenu, "Mask", BitOR($MIIM_ID, $MIIM_STRING, $MIIM_SUBMENU))
        $tText = DllStructCreate("wchar Text[" & StringLen($sText) + 1 & "]")
        DllStructSetData($tText, "Text", $sText)
        DllStructSetData($tMenu, "TypeData", DllStructGetPtr($tText))
    EndIf
    _GUICtrlMenu_InsertMenuItemEx ($hMenu, $iIndex, $tMenu)
EndFunc   ;==>InsertItem