Function Reference

_GUICtrlMenu_SetItemBitmaps

指定されたビットマップをメニューアイテムに関連付けします。

#Include <GuiMenu.au3>
_GUICtrlMenu_SetItemBitmaps($hMenu, $iItem, $hChecked, $hUnChecked[, $fByPos = True])

 

パラメータ

$hMenu メニューハンドル
$iItem メニューアイテムの位置または識別子
$hChecked メニューアイテムが選択されている際に表示されるビットマップのハンドル
$hUnChecked メニューアイテムが選択さていない際に表示されるビットマップのハンドル
$fByPos [オプション]メニュー識別子フラグ:
 True - $iItemはゼロ始まりのアイテム位置です
False - $iItemはメニューアイテムの識別子です

 

返し値

成功: True
失敗: False

 

注意

hBitmapUncheckedパラメータとhBitmapCheckedパラメータのどちらかが0の場合、システムはメニューアイテムの隣にチェック状態を表示しません。
もし両方のパラメータが0の場合、システムはアイテム選択時にデフォルトのチェックマークビットマップを表示し、非選択時にそのビットマップを消します。

 

関連

_GUICtrlMenu_SetItemBmpChecked, _GUICtrlMenu_SetItemBmpUnchecked

 

こちらも参照

MSDNライブラリでSetMenuItemBitmapsを検索して下さい。

 


#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>

Opt('MustDeclareVars', 1)

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain, $hBmp1, $hBmp2
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; GUIを作成
    $hGUI = GUICreate("Menu", 400, 300)

    ; ファイルメニューを作成
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hFile, 0, "&New", $idNew)
    _GUICtrlMenu_InsertMenuItem ($hFile, 1, "&Open", $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hFile, 2, "&Save", $idSave)
    _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hFile, 4, "E&xit", $idExit)

    ; 編集メニューを作成
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hEdit, 0, "&Cut", $idCut)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 1, "C&opy", $idCopy)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 2, "&Paste", $idPaste)

    ; ヘルプメニューを作成
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hHelp, 0, "&About", $idAbout)

    ; メインメニューを作成
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem ($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem ($hMain, 2, "&Help", 0, $hHelp)

    ; ウィンドウにメニューを設定
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)

    ; メモコントロールを作成
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; ファイルメニューにチェック/非チェックのビットマップを設定
    $hBmp1 = _WinAPI_CreateSolidBitmap ($hGUI, 0xFF0000, 11, 11)
    $hBmp2 = _WinAPI_CreateSolidBitmap ($hGUI, 0x00FF00, 11, 11)
    _GUICtrlMenu_SetItemBitmaps ($hFile, 0, $hBmp1, $hBmp2)
    _GUICtrlMenu_SetItemBitmaps ($hFile, 1, $hBmp1, $hBmp2)
    _GUICtrlMenu_SetItemBitmaps ($hFile, 2, $hBmp1, $hBmp2)

    ; "開く"メニューアイテムをチェック
    _GUICtrlMenu_CheckMenuItem ($hFile, 1)

    ; ビットマップハンドルが一致するかを表示
    MemoWrite("Checked handle ......: 0x" & Hex($hBmp1))
    MemoWrite("Unchecked handle ....: 0x" & Hex($hBmp2))
    MemoWrite("Open checked handle .: 0x" & Hex(_GUICtrlMenu_GetItemBmpChecked ($hFile, 0)))
    MemoWrite("Open unchecked handle: 0x" & Hex(_GUICtrlMenu_GetItemBmpUnchecked ($hFile, 0)))

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite