Function Reference

_GUICtrlRichEdit_AutoDetectURL

URLSの自動検出を有効または無効にします。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_AutoDetectURL($hWnd, $fState)

 

パラメータ

$hWnd コントロールのハンドル
$fState テキスト内のURLを検出する場合はTrue、しない場合はFalse

 

返し値

成功: True
失敗: Falseを返し、@errorを設定します。
@error: 101 - $hWndがハンドルではありません。
102 - $fStateがTrueでもFalseでもありません。
700 - 内部エラー。例: メモリ不足

 

注意

有効にした場合、変更されたテキストがURL形式に適合するテキストかどうかスキャンされます。
以下の語から始まる文字列はURLとして検出されます: http:, file:, mailto:, ftp:, https:, gopher:, nntp:, prospero: ,telnet:, news:, wais:。
URLが検出されるとWindowsはURL文字列のすべての文字にリンク属性を設定し、文字列を強調表示します。

URLの自動検出がオンの場合にURLが検出されるとWindowsはURLでない全ての文字からリンク属性を削除します。

発生通知に対しては$ENM_LINKを使って_GUICtrlRichEdit_SetEventMaskを呼んで下さい。

 

関連

_GUICtrlRichEdit_SetEventMask

 

こちらも参照

MSDNライブラリでnotificationを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
    _GuiCtrlRichEdit_SetEventMask($hRichEdit, $ENM_LINK)

    _GuiCtrlRichEdit_AutoDetectURL($hRichEdit, True)
    _GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "http://www.autoitscript.com")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GuiDelete()
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
    #forceref $hWnd, $iMsg, $iWparam
    Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $cpMin, $cpMax, $tMsgFilter
    $tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hRichEdit
            Select
                Case $iCode = $EN_LINK
                    $tMsgFilter = DllStructCreate($tagEN_MSGFILTER, $iLparam)
                    If DllStructGetData($tMsgFilter, "msg") = $WM_LBUTTONUP Then
                        $tEnLink = DllStructCreate($tagENLINK, $iLparam)
                        $cpMin = DllStructGetData($tEnLink, "cpMin")
                        $cpMax = DllStructGetData($tEnLink, "cpMax")
                        MsgBox(0, "", "Invoke your web browser here and point it to " & _
                                _GuiCtrlRichEdit_GetTextInRange($hRichEdit, $cpMin, $cpMax))
                    EndIf
            EndSelect
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY