エディットコントロールを作成します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_Create($hWnd, $sText, $iLeft, $iTop[, $iWidth = 150[, $iHeight = 150[, $iStyle = -1[, $iExStyle = -1]]]])
パラメータ
| $hWnd | 親ウィンドウまたはオーナーウィンドウのハンドル |
| $sText | コントロールに表示されるテキスト |
| $iLeft | コントロールの水平位置 |
| $iTop | コントロールの垂直位置 |
| $iWidth | [オプション] コントロールの幅 |
| $iHeight | [オプション] コントロールの高さ |
| $iStyle | [オプション] コントロールのスタイル: $ES_AUTOHSCROLL - ユーザーが行末に文字を入力する際に10文字毎に自動的にテキストを右にスクロールします。 $ES_AUTOVSCROLL - ユーザーが行末でENTERキーを押した際に自動的にテキストを1ページ上にスクロールします。 $WS_HSCROLL - コントロールに水平スクロールバーを設定します。 $WS_VSCROLL - コントロールに垂直水平スクロールバーを設定します。 $ES_CENTER - エディットコントロール内のテキストを中央揃えにします。 $ES_LEFT - テキストを左余白に揃えます。 $ES_MULTILINE - 複数行のコントロールを作成します(デフォルト)。 $ES_NOHIDESEL - コントロールにフォーカスが合っていない場合でも選択されたテキストを反転します。 $ES_NUMBER - エディットコントロールに数値のみ入力できるようにします。 $ES_READONLY - ユーザーがエディットコントロール内でテキストを編集したり、入力できないようにします。 $ES_RIGHT - エディットコントロールのテキストを右揃えにします。 $ES_WANTRETURN - ユーザーがENTERキーを押した際キャリッジリターンが挿入されるように指定します(デフォルト)。 $ES_PASSWORD - エディットコントロールに入力された各文字としてアスタリスク(*)を表示します。 |
| Default: 0 強制 : WS_CHILD, $WS_VISIBLE, $ES_READONLYでない場合$WS_TABSTOP() |
|
| $iExStyle | [オプション] コントロールの拡張スタイル。標準の$WS_EX_ 定数と対応します。 |
返し値
| 成功: | リッチエディットコントロールのハンドル |
| 失敗: | 0を返し、@errorを設定します: |
| @error: | 103 - $iLeftが正の数でもゼロでもありません。 |
| 104 - $iTopが正の数でもゼロでもありません。 | |
| 105 - $iWidthが正の数でも-1でもありません。 | |
| 106 - $iHeightが正の数でも-1でもありません。 | |
| 107 - $iStyleが正の数でもゼロでも-1でもありません。 | |
| 108 - $iExStyleが正の数でもゼロでも-1でもありません。 |
注意
スクリプトを終了する前に必ず_GUICtrlRichEdit_Destroy()を呼ばなければなりません。
関連
_GUICtrlRichEdit_Destroy
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Main()
Func Main()
Local $hGui, $hRichEdit, $iMsg
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "This is more text")
GUISetState()
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
EndSelect
WEnd
EndFunc ;==>Main