Function Reference

_GUICtrlRichEdit_Deselect

テキスト洗濯を解除し、非選択状態にします。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_Deselect($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: True
失敗: Falseを返し、@errorを設定します。
@error: 101 - $hWndがハンドルではありません。

 

注意

挿入位置は選択の末尾位置に移動します。

 

関連

_GUICtrlRichEdit_SetSel, _GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_IsTextSelected

 

こちらも参照

MSDNライブラリでEM_SETSELを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $ai, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GuiCtrlRichEdit_SetSel($hRichEdit, 5, 12)
                        $ai = _GuiCtrlRichEdit_GetSel($hRichEdit)
                        Report("1.Text is selected from inter-character position " & $ai[0] & " to " & $ai[1])
                    Case 2
                        _GuiCtrlRichEdit_DeSelect($hRichEdit)
                        $ai = _GuiCtrlRichEdit_GetSel($hRichEdit)
                        If $ai[0] = $ai[1] Then Report("2.No text is selected now")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report