Function Reference

_GUICtrlRichEdit_GetLineLength

行の長さを取得します。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineLength($hWnd, $iLine)

 

パラメータ

$hWnd コントロールのハンドル
$iLine 行番号
特殊な値: -1 - 選択された文字を含む行の選択されてない文字の数を返します。

 

返し値

成功: 複数行のコントロール - 行の長さ (文字数単位)
1行のコントロール - コントロール内の文字数
失敗: 0を返し、@errorを設定します:
@error: 101 - $hWndがハンドルではありません。
102 - $iLineは正の数でも-1でもありません。
1022 - $iLineがコントロール内の文字数よりも大きい値です。

 

注意

テキストが存在しない テキストが存在しないコントロールは1行と見なされます。
コントロールの最初の文字間位置は0です。

結果には行末尾のキャリッジリターン文字は含まれません。

 

関連

 

こちらも参照

MSDNライブラリでEM_GETLINELENGTHを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $hRichEdit, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    Report("The current line contains " & _GUICtrlRichEdit_GetLineLength($hRichEdit, -1) & " characters")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report