Function Reference

_GUICtrlRichEdit_GetParaIndents

(最初の)選択された段落、または(選択されていない場合)現在の段落のインデント設定を取得します。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaIndents($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: 文字列 - セミコロン(;)で区切られた値で構成された文字列:
値1 - Left - 段落本文の(2行目以降の)左側へのインデント (スペースの単位)
値2 - Right - 段落右側へのインデント(スペースの単位)
値3 - FirstLine - 他の行に対して1行目をインデント (スペースの単位)
値4 - 範囲:
a - 選択された全て(または最初)の段落に設定されています。
f - 最初の選択された段落にのみ設定されています。
c - 現在の段落に設定されています。
失敗: ""を返し、@errorを設定します。
@error: 101 - $hWndがハンドルではありません。

 

注意

$iLeft、$iRight、$iFirstLineの正の値は段落中央に向かってのインデントを表します。

 

関連

_GUICtrlRichEdit_SetParaIndents

 

こちらも参照

MSDNライブラリでEM_GETPARAFORMATを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
    Report("Para with default indent settings")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        Report("Added second paragraph")
                    Case 2
                        _GUICtrlRichEdit_SetParaIndents($hRichEdit, 0.25, .1)
                        Report("Changed indent settings of second paragraph")
                    Case 3
                        _GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaIndents($hRichEdit, Default, 0, .2)
                        Report("Change settings of both paragraphs")
                    Case 4
                        ; Wordでインデント設定を確認できるように全てのテキストをデスクトップに保存
                        _GuiCtrlRichEdit_Deselect($hRichEdit)
                        _GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaIndents($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report