(最初の)選択された段落、または(選択されていない場合)現在の段落のタブストップを取得します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaTabStops($hWnd)
パラメータ
| $hWnd | コントロールのハンドル |
返し値
| 成功: | ; (セミコロン)で区切られた値で構成される文字列 |
| 値1 - タブストップ数 | |
| 値2 から <値1> + 1 - タブストップの情報: | |
| タブストップの絶対位置(スペースの単位) | |
| タブの種類 | |
| l - 左タブ | |
| c - 中央タブ | |
| r - 小数点タブ | |
| b - バータブ (Wordでの垂直バー) | |
| リーダーの種類 | |
| . - ドットのリーダー | |
| - - ダッシュのリーダー | |
| _ - 下線のリーダー | |
| = - 二重線のリーダー | |
| t - 太線のリーダー | |
| スペース - リーダー無し | |
| 値 <値1> + 2 - 範囲: | |
| a - 選択された全て(または最初)の段落に設定されています。 | |
| f - 最初の選択された段落にのみ設定されています。 | |
| c - 現在の段落に設定されています。 | |
| 失敗: | ""を返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
注意
コントロールにタブを入力するにはCtrl_Tabを押して下さい。
関連
_GUICtrlRichEdit_SetParaTabStops
こちらも参照
MSDNライブラリでEM_GETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("0. Para with default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaTabStops($hRichEdit, ".3l ;1c ;2.5r.")
Report("1. TabStops of second paragraph")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("2. Tabstops of first paragraph")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
Report("Tabstops of first paragraph in selection")
Case 4
_GUICtrlRichEdit_SetParaTabStops($hRichEdit, "2.3r=")
Report("3. Change tabstops of both paragraphs")
Case 5
; Wordで設定を確認できるように全てのテキストをデスクトップに保存
_GuiCtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaTabStops($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report