Function Reference

_GUICtrlRichEdit_GetSelAA

選択の開始位置と終了位置を順に取得します。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSelAA($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: [<終了位置>, <開始位置>] 形式の配列
失敗: @errorを設定します。
@error: -1 - テキストが選択されていません。
101 - $hWndがハンドルではありません。

 

注意

テキストの最初の文字は文字間位置0の後ろです。

 

関連

_GUICtrlRichEdit_SetSel, _GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_GetScrollPos

 

こちらも参照

MSDNライブラリでEM_EXGETSELを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)


Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GuiCtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
    _GuiCtrlRichEdit_SetSel($hRichEdit, 7, 2)
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Selection is high to low")
                    Case 2
                        _GuiCtrlRichEdit_SetSel($hRichEdit, 2, 7)
                        Report("2. Selection is low to high")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aRet = _GUICtrlRichEdit_GetSelAA($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & "Get function returns " & $aRet[0] & "," & $aRet[1]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report