Function Reference

_GUICtrlRichEdit_IsModified

リッチエディットコントロールの変更フラグの状態を取得します。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_IsModified($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: TrueまたはFalse
失敗: @errorを設定します。
@error: 101 - $hWndがハンドルではありません。

 

注意

コントロールが作成された際にシステムは自動的に変更フラグをFalseに設定します。
ユーザー、またはプログラムによってコントロールのテキストが変更されるとシステムはこのフラグをTrueに設定します。
このフラグを設定、初期化したい場合は_GUICtrlRichEdit_SetModifiedを呼んで下さい。

 

関連

_GUICtrlRichEdit_SetModified, _GUICtrlRichEdit_GetText

 

こちらも参照

MSDNライブラリでEM_GETMODIFYを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    Report("Initial state after creation")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "A paragraph")
                        Report("Added some text")
                    Case 2
                        _GuiCtrlRichEdit_SetModified($hRichEdit, False)
                        Report("After clearing the modification flag")
                    Case 3
                        GUICtrlSetData($lblMsg, "Type some text. Then click on Next")
                        ControlFocus($hRichEdit, "", "")
                    Case 4
                        Report("After typing")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "State is " & _GUICtrlRichEdit_IsModified($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report