1行分、または1ページ分、テキストをスクロールします。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollLineOrPage($hWnd, $sAction)
パラメータ
| $hWnd | コントロールのハンドル |
| $sAction | 次のいずれか: "ld" - 1行下 "lu" - 1行上 "pd" - 1ページ下 "pu" - 1ページ上 |
返し値
| 成功: | 実際にスクロールした行数(下方向のスクロールが正) |
| 失敗: | 0を返し、@errorを設定します: |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $sActionが2文字ではありません。 | |
| 1022 - 1文字目はlまたはpでなければなりません。 | |
| 1023 - 2文字目はdまたはuでなければなりません。 |
注意
最後の1行の表示を超えた行数はスクロールされません。これはこの関数の仕様です。
関連
_GUICtrlRichEdit_ScrollLines, _GUICtrlRichEdit_ScrollToCaret
こちらも参照
MSDNライブラリでEM_SCROLLを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
For $i = 1 To 20
_GUICtrlRichEdit_AppendText($hRichEdit, "Line " & $i & @CR)
Next
_GUICtrlRichEdit_AppendText($hRichEdit, "Line 21")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
DoIt("lu", "Scrolled up a line")
Case 2
DoIt("pu", "Scrolled up a page")
Case 3
DoIt("pd", "Scrolled down a page")
Case 4
DoIt("pd", "Tried to scroll down another page")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func DoIt($sAction, $sMsg)
Local $iQlines
$iQlines = _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, $sAction)
GUICtrlSetData($lblMsg, $sMsg & @CR & @CR & "Actually scrolled " & @CR & $iQlines & " lines")
EndFunc ;==>DoIt