選択されているテキストのある段落のスペース設定を設定します。選択されていない場合、挿入位置に挿入されるテキストのスペース設定を設定します。
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaSpacing($hWnd, [$vInter=Default [, $iBefore=Default [, $iAfter=Default]]])
パラメータ
| $hWnd | コントロールのハンドル |
| $vInter | [オプション] 行間スペース: 次のどちらか 数値 - スペースの単位 "行数<n>" - 行数単位 |
| $iBefore | [オプション] パラグラフ直前のスペース (スペースの単位) |
| $iAfter | [オプション] パラグラフ直後のスペース (スペースの単位) |
返し値
| 成功: | True |
| 失敗: | Falseを返し、@errorを設定します。 |
| @error: | 101 - $hWndがハンドルではありません。 |
| 1021 - $vInterが不正です。 | |
| 1022 - "行数<n>"として設定できるのは1、1.5、2のいずれかのみです。 | |
| 103 - $iBeforeが正の数でもゼロでもありません。 | |
| 104 - $iAfterが正の数でもゼロでもありません。 |
注意
デフォルト値とは異なる値のみ設定できます。
関連
_GUICtrlRichEdit_GetParaSpacing, _GUICtrlRichEdit_SetSpaceUnit
こちらも参照
MSDNライブラリでEM_SETPARAFORMATを検索して下さい。
例
#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $btnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("0. Para with default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GuiCtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaSpacing($hRichEdit, "2 lines", .2, .25)
Report("1. Spacing of second paragraph is ")
Case 2
_GuiCtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("2. Settings of first paragraph in the selection are ")
Case 3
_GuiCtrlRichEdit_SetSel($hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaSpacing($hRichEdit, Default, .1)
Report("3. Change spacing of both paragraphs")
Case 4
; Wordでインデント設定を確認できるように全てのテキストをデスクトップに保存
_GUICtrlRichEdit_Deselect($hRichEdit)
_GuiCtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaSpacing($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report