Function Reference

_GUICtrlRichEdit_SetUndoLimit

アンドゥ用キューに保持できる操作の最大数を設定します。

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetUndoLimit($hWnd, $iLimit)

 

パラメータ

$hWnd コントロールのハンドル
$iLimit アンドゥ用キューに保持できる操作の最大数

 

返し値

成功: True
失敗: Falseを返し、@errorを設定します。
@error: 101 - $hWndがハンドルではありません。
102 - $iLimitが正の数でもゼロでもありません。

 

注意

アンドゥ機能を無効にするには$iLimitをゼロに設定して下さい。

$iLimitの初期値は100です。

 

関連

_GUICtrlRichEdit_Undo, _GUICtrlRichEdit_CanRedo, _GUICtrlRichEdit_CanUndo, _GUICtrlRichEdit_GetNextRedo, _GUICtrlRichEdit_Redo

 

こちらも参照

MSDNライブラリでEM_SETUNDOLIMITを検索して下さい。

 


#AutoIt3Wrapper_Au3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName,4) &")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GuiCtrlRichEdit_SetText($hRichEdit, "First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                GUIDelete()
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetUndoLimit($hRichEdit, 200)
                        GUICtrlSetData($lblMsg, "Increased the number of actions that can stored in the undo queue from 100 to 200")
                    Case 2
                        _GUICtrlRichEdit_SetUndoLimit($hRichEdit, 0)
                        GUICtrlSetData($lblMsg, "Undo is disabled")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main