Function Reference

_GUICtrlSlider_GetLogicalTics

スライダーの目盛りの論理位置を格納した配列を取得します。

#Include <GuiSlider.au3>
_GUICtrlSlider_GetLogicalTics($hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: 論理位置の配列を返します
失敗: @errorが設定されます

 

注意

配列内の要素数は_GUICtrlSlider_GetNumTicsが返す目盛り総数よりも2小さい数です。
配列内の値は位置の重複を含むことがあり、また位置の順番と一致していません。
返された配列内のデータはスライダーの目盛りを変更するまで有効です。

スライダー目盛りの論理位置を指定する配列の要素にはスライダーによって作成される最初と最後の目盛りは含まれません。
論理位置はスライダーの最小最大スライダー位置範囲内の任意の整数値です。

 

関連

 


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiSlider.au3>

Opt('MustDeclareVars', 1)

$Debug_S = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

Global $iMemo

_Main()

Func _Main()
    Local $hSlider, $aTics

    ; GUIを作成
    GUICreate("Slider Get Logical Tic Positions", 400, 296)
    $hSlider = GUICtrlCreateSlider(2, 2, 300, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $aTics = _GUICtrlSlider_GetLogicalTics($hSlider)
    MemoWrite("Number Tics Excluding 1st and last .....: " & UBound($aTics))
    For $x = 0 To UBound($aTics) - 1
        MemoWrite(StringFormat("(%02d) Logical Tick Position .............: %d", $x, $aTics[$x]))
    Next

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; メモコントロールに1行書き込み
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite