Function Reference

_GUICtrlStatusBar_Destroy

コントロールを削除します。

#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_Destroy(ByRef $hWnd)

 

パラメータ

$hWnd コントロールのハンドル

 

返し値

成功: True、ハンドルが0に設定されます
失敗: False

 

注意

_GUICtrlStatusBar_Createで作成されたステータスバーにのみ使用できます。

 

関連

_GUICtrlStatusBar_Create

 


#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>

Opt('MustDeclareVars', 1)

$Debug_SB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用

_Main()

Func _Main()

    Local $hGUI, $HandleBefore, $hStatus
    Local $aParts[3] = [75, 150, -1]
   
    ; GUIを作成
    $hGUI = GUICreate("StatusBar Destroy", 400, 300)

    ;===============================================================================
    ; デフォルト 1パーツ、テキストなし
    $hStatus = _GUICtrlStatusBar_Create ($hGUI)
    ;===============================================================================
    _GUICtrlStatusBar_SetParts ($hStatus, $aParts)

    GUISetState()

    $HandleBefore = $hStatus
    MsgBox (4160, "Information", "Destroying the Control for Handle: " & $hStatus)
    MsgBox (4160, "Information", "Control Destroyed: " & _GUICtrlStatusBar_Destroy ($hStatus) & @LF & _
            "Handel Before Destroy: " & $HandleBefore & @LF & _
            "Handle After Destroy: " & $hStatus)

    ; ユーザーが終了するまでループ
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main