パーツの外接長方形を取得します。
#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetRect($hWnd, $iPart)
パラメータ
| $hWnd | コントロールのハンドル |
| $iPart | ゼロ始まりのパーツインデックス |
返し値
| 成功: | 次のフォーマットの配列: |
| $aRect[0] = 長方形の左上隅のX座標 | |
| $aRect[1] = 長方形の左上隅のY座標 | |
| $aRect[2] = 長方形の右下隅のX座標 | |
| $aRect[3] = 長方形の右下隅のY座標 | |
| 失敗: | @errorを設定します。 |
注意
なし。
関連
_GUICtrlStatusBar_GetRectEx
例
#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_SB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $aRect, $hStatus
Local $aParts[3] = [75, 150, -1]
; GUIを作成
$hGUI = GUICreate("StatusBar Get Rect", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; パーツを設定/取得
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
; パーツ1の長方形を取得
$aRect = _GUICtrlStatusBar_GetRect ($hStatus, 0)
MemoWrite("Part 1 left ...: " & $aRect[0])
MemoWrite("Part 1 top ....: " & $aRect[1])
MemoWrite("Part 1 right ..: " & $aRect[2])
MemoWrite("Part 1 bottom .: " & $aRect[3])
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite