パーツの外接長方形を取得します。
#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetRectEx($hWnd, $iPart)
パラメータ
$hWnd | コントロールのハンドル |
$iPart | ゼロ始まりのパーツインデックス。 コントロールがシンプルモードの場合、この値は無視されステータスバーの長方形が返されます。 |
返し値
成功: | 外接長方形を受け取った$tagRECT構造体 |
失敗: | @errorを設定します。 |
注意
なし。
関連
_GUICtrlStatusBar_GetRect, $tagRECT
例
#include <GuiConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)
$Debug_SB = False ; 関数に渡されるClassNameを調べる。動作を確認するにはTrueを設定し、他のコントロールのハンドルを使用
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $tRect, $hStatus
Local $aParts[3] = [75, 150, -1]
; GUIを作成
$hGUI = GUICreate("StatusBar Get RectEx", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
; メモコントロールを作成
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; パーツを設定/取得
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
; パーツ1の長方形を取得
$tRect = _GUICtrlStatusBar_GetRectEx ($hStatus, 0)
MemoWrite("Part 1 left ...: " & DllStructGetData($tRect, "Left"))
MemoWrite("Part 1 top ....: " & DllStructGetData($tRect, "Top"))
MemoWrite("Part 1 right ..: " & DllStructGetData($tRect, "Right"))
MemoWrite("Part 1 bottom .: " & DllStructGetData($tRect, "Bottom"))
; ユーザーが終了するまでループ
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; メモ帳にメッセージを書き込む
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite